TARGET = imapquickcheck
CONFIG += release
QT += sql
QT += printsupport
TEMPLATE = app
OBJECTS_DIR += build
MOC_DIR += build
UI_DIR += build
SOURCES += main.cpp \
    SystrayIcon.cpp \
    PrefsDialog.cpp
HEADERS += SystrayIcon.h \
    PrefsDialog.h \
    SettingsInfo.h
RESOURCES += ImapQuickCheck.qrc
FORMS += ui/prefs.ui
TRANSLATIONS += ts/imapquickcheck_fr.ts \
                ts/imapquickcheck_de.ts \
                ts/imapquickcheck_sp.ts \
                ts/imapquickcheck_it.ts \
                ts/imapquickcheck_pt.ts \
                ts/imapquickcheck_pl.ts \
                ts/imapquickcheck_ru.ts
# Unix installer.
unix { 
    isEmpty(PREFIX):PREFIX = /usr
    isEmpty(BINDIR):BINDIR = $$PREFIX/bin
    isEmpty(DATAROOT):DATAROOT = $$PREFIX/share
    isEmpty(DESKTOPDIR):DESKTOPDIR = $$DATAROOT/applications
    #isEmpty(IMAGEDIR):IMAGEDIR = $$DATAROOT/pixmaps
    isEmpty(TRANSLATIONSDIR):TRANSLATIONSDIR = $$DATAROOT/imapquickcheck/translations
    target.path = $$BINDIR
    desktop.path = $$DESKTOPDIR
    desktop.files = imapquickcheck.desktop
    #icons.path = $$IMAGEDIR
    #icons.files = imapquickcheck.png
    translations_qm.path = $$TRANSLATIONSDIR
    translations_qm.files = ts/*.qm
    INSTALLS += target desktop translations_qm
}